TRUE Forex

Просмотр кода форекс индикатора !X-UK.NMA.4.mq4

// FOR THOSE OF YOU THAT IMPROVE UPON THIS HERE CODE I ASK YOU ONE THING
// PLEASE POST A COPY UP ON THE FOREX FORUMS FOR YOUR FELLOW TRADERS

#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1  C'0,255,165'
#property indicator_color2  C'0,255,165'//Gold//C'165,0,128'
#property indicator_color3  C'0,255,165'//Gold//C'165,0,128'
#property indicator_width1  4
#property indicator_width2  4
#property indicator_width3  4

//
//
//
//
//

int    NMA_Length        = 16;
int    NMA_Sample_Length = 4;
int    MA_Method         = MODE_EMA;
int    MA_Price          = PRICE_TYPICAL;

double nma[];
double nmada[];
double nmadb[];
double nma_s[];
double slope[];

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

int init()
{
   IndicatorDigits(5);
   IndicatorBuffers(5);
      string label = "NMA (" + NMA_Length + "," +  NMA_Sample_Length + ")";
      SetIndexBuffer(0,nma);   SetIndexLabel(0,label);
      SetIndexBuffer(1,nmada); SetIndexLabel(1,label);
      SetIndexBuffer(2,nmadb); SetIndexLabel(2,label);
      SetIndexBuffer(3,nma_s);
      SetIndexBuffer(4,slope);
   IndicatorShortName("NMA");
   return(0);
}

//------------------------------------------------------------------
//
//------------------------------------------------------------------

int start()
{
   int i,count,counted_bars=IndicatorCounted();
      if(counted_bars < 0) return(-1);
      if(counted_bars>0) counted_bars--;
         int limit = MathMin(Bars-counted_bars,Bars-1);
         if (slope[limit]==-1) CleanPoint(limit,nmada,nmadb);

      double Lambda = NMA_Length / NMA_Sample_Length;
      if(Lambda < 2.0)
      {
         Lambda = 2.0;
         NMA_Sample_Length = NMA_Length / 2.0;
      }
      double Alpha  = Lambda * (NMA_Length - 1.0) / (NMA_Length - Lambda);

      for (i = limit; i >= 0; i--)  nma_s[i] = iMA(NULL, 0, NMA_Length, 0, MA_Method, MA_Price, i);
      for (i = limit; i >= 0; i--)
      {   
         double Gamma     = iMAOnArray(nma_s,0,NMA_Sample_Length,0,MA_Method,i);
                nma[i]   = (Alpha+1.0)*nma_s[i] - Alpha*Gamma;
                slope[i] = slope[i+1];
                  if (nma[i]>nma[i+1]) slope[i] =  1; 
                  if (nma[i]<nma[i+1]) slope[i] = -1; 
                  if (slope[i]==-1) PlotPoint(i,nmada,nmadb,nma);
      }
      return(0);
}

//-------------------------------------------------------------------
//
//-------------------------------------------------------------------
//
//
//
//
//

void CleanPoint(int i,double& first[],double& second[])
{
   if ((second[i]  != EMPTY_VALUE) && (second[i+1] != EMPTY_VALUE))
        second[i+1] = EMPTY_VALUE;
   else
      if ((first[i] != EMPTY_VALUE) && (first[i+1] != EMPTY_VALUE) && (first[i+2] == EMPTY_VALUE))
          first[i+1] = EMPTY_VALUE;
}

//
//
//
//
//

void PlotPoint(int i,double& first[],double& second[],double& from[])
{
   if (first[i+1] == EMPTY_VALUE)
      {
         if (first[i+2] == EMPTY_VALUE) {
                first[i]   = from[i];
                first[i+1] = from[i+1];
                second[i]  = EMPTY_VALUE;
            }
         else {
                second[i]   =  from[i];
                second[i+1] =  from[i+1];
                first[i]    = EMPTY_VALUE;
            }
      }
   else
      {
         first[i]  = from[i];
         second[i] = EMPTY_VALUE;
      }
}

Комментарии к исходному коду форекс индикатора !X-UK.NMA.4.mq4
В целях безопасности и борьбы со спамом в тексте комментариев запрещено размещать html-теги и ссылки. Благодарим за понимание.

  • X
  • 0% загружено
« индикатор !X-UK.INFO.BOX.mq4
индикатор !X-UK.TREND.mq4 »